Think: Something you'd put on your desk and glance at occasionally. Something calming. Something that makes you smile when you interact with it, then settles back down.

Copy All Code

/*
 * AmbientTouchToy_Starter.ino
 * V1: Basic Structure Example
 *
 * This is a STARTING POINT - not a finished project!
 * Use this pattern, but make your own concept.
 */

#include <Adafruit_GFX.h>
#include <Adafruit_SH110X.h>
#include <Wire.h>

Adafruit_SH1106G display = Adafruit_SH1106G(128, 64, &Wire, -1);

// Touch pins
const int TOUCH_PIN = 1;  // Use more pins for more interactions!
const int TOUCH_THRESHOLD = 80000;

// Animation state
float intensity = 0.5;           // Current intensity (0.0 to 1.0)
float targetIntensity = 0.5;    // Where we're heading
float defaultIntensity = 0.5;   // Peaceful default
float activeIntensity = 1.0;    // When touching

float timeStep = 0;
unsigned long lastTouchTime = 0;
const int RETURN_DELAY = 1000;  // ms before returning to default

void setup() {
  Serial.begin(115200);
  Wire.begin(5, 6);
  Wire.setClock(400000);
  display.begin(0x3C, true);
  display.clearDisplay();
  display.display();
}

void loop() {
  timeStep += 0.05;

  // === 1. READ TOUCH ===
  bool touching = touchRead(TOUCH_PIN) > TOUCH_THRESHOLD;

  // === 2. UPDATE TARGET BASED ON TOUCH ===
  if (touching) {
    lastTouchTime = millis();
    targetIntensity = activeIntensity;  // Ramp up!
  } else {
    // Return to default after delay
    if (millis() - lastTouchTime > RETURN_DELAY) {
      targetIntensity = defaultIntensity;
    }
  }

  // === 3. SMOOTH INTERPOLATION ===
  // This is the key! Never jump, always glide.
  intensity = intensity * 0.95 + targetIntensity * 0.05;

  // === 4. DRAW YOUR ANIMATION ===
  display.clearDisplay();

  // TODO: Replace this with YOUR animation!
  // Use 'intensity' to control how active/calm things are

  // Example: A simple pulsing circle that grows when touched
  int baseSize = 10;
  int pulseAmount = 5 * intensity;
  int pulse = sin(timeStep * (1 + intensity * 3)) * pulseAmount;

  display.drawCircle(64, 32, baseSize + pulse + (intensity * 15), SH110X_WHITE);

  // Show intensity for debugging (remove in final version)
  display.setTextSize(1);
  display.setTextColor(SH110X_WHITE);
  display.setCursor(0, 0);
  display.print("Int: ");
  display.print(intensity, 2);

  display.display();
  delay(16);
}

This starter is intentionally boring! It's just a pulsing circle. Your job is to replace it with something beautiful and meaningful to you.

Tips for good video: Film in landscape mode. Make sure the OLED screen is visible and in focus. Natural lighting works best. You can use your phone propped up or ask a friend to film.